VBA: macro para obtener rango de celdas asociado a una selección.

Tiempo atrás expliqué como mediante el uso de un objeto Collection en una macro de Excel conseguíamos un listado de valores únicos de una forma muy sencilla (ver entrada).
Esta entrada nos servirá para responder la cuestión planteada, en la que se pide extraer los valores asociados a un dato previamente seleccionado; y veremos como podemos combinar diferentes Eventos sobre un mismo control(ActiveX) para conseguir diferentes efectos, en este ejemplo, usaremos el evento GotFocus y el evento Change.
Esta es la cuestión:

...La siguiente lista me muestra que en la columna A tengo un dato y en la columna B me muestra todos los valores asociados a la celda de la columna A. La pregunta es cómo puedo buscar, utilizando el dato de la columna A, los datos de asociados de la columna B...

Veamos la imagen de la tabla origen:

Se puede observar en la imagen que en la columna A (campo 'Código') existen varios valores repetidos (ax, bx, cx, dx, etc.), y que asociados a estos, en la columna B (campo 'Descripción') les corresponden diferentes valores; para ax le toca ax-01, ax-02, ax-03 y ax-04; y así sucesivamente.
La idea es ser capaz de seleccionar un elemento único del campo 'Código' para de manera inmediata se despliegue en la Hoja de cálculo los valores asociados del campo 'Descripción'.
Para trabajar de manera más cómoda hemos convertido en Tabla el origen de datos, asignando además Nombres definidos a ambos campos:
Código =Hoja1!$A$2:$A$12
Descripción =Hoja1!$B$2:$B$12
El siguiente paso es sencillo, insertaremos desde la Ficha Programador > Controles > Insertar > Control ActiveX > Cuadro Combinado, es decir, insertaremos un control ComboBox en la hoja de cálculo, al que asignaremos para empezar un evento GotFocus, que habilitará el listado de valores únicos como elementos (items) del ComboBox al presionarlo.
Al hacer click sobre el Cuadro Combinado recien insertado se abre una ventana de código (en la Hoja1) en la que insertaremos lo siguiente:

Private Sub comboBox1_gotfocus()

Dim celda As Object
Dim i As Integer

ComboBox1.Clear
Set unicos = New Collection

For Each celda In Range("Código")
    On Error Resume Next
    unicos.Add celda.Value, CStr(celda.Value)
    On Error GoTo 0
Next celda

For i = 1 To unicos.Count
    ComboBox1.AddItem unicos(i)
Next i

End Sub

Con esto hemos conseguido rellenar el ComboBox con los elementos únicos que componen en campo 'Código', como vemos en la imagen:

De momento el ComboBox no hace nada más, pero si añadimos a continuación un nuevo evento Change sobre él mismo, conseguiremos nuestro objetivo, que es listar los valores del campo 'Descripción' asociados a nuestra selección.
Asi que a continuación del código anterior escribimos:

Private Sub comboBox1_change()
Dim seleccionado As Variant
seleccionado = ComboBox1.Value
x = 0
Range(Range("E4"), Range("E4").End(xlDown)).Clear
Range("E4").Select
Dim celda2 As Object
For Each celda2 In Range("Código")
    If celda2.Value = seleccionado Then
    ActiveCell.Offset(x, 0).Value = celda2.Offset(0, 1)
    x = x + 1
    End If
Next celda2
End Sub

Con este segundo código, con el evento Change, indicamos que al seleccionar algún elemento del Cuadro combinado (ComboBox) liste, a partir de la celda E4 de la hoja las diferentes 'Descripciones' asociadas.
Podemos ver el resultado en la imagen: