martes, 3 de noviembre de 2020

Probabilidad Sumar 7 con dos dados

Hoy un artículo sobre la probabilidad de obtener un siete al lanzar dos dados.
Para los amantes del azar o de las probabilidades.
Probabilidad Sumar 7 con dos dados

La probabilidad 'pura' nos dice para este caso que la probabilidad de obtener un determinado valor total de dados (siete para nuestro ejemplo), se puede calcular tomando el número total de maneras diferentes de conseguir ese total y dividiéndolo por el total de resultados distinguibles.
Es fácil distinguir las 36 combinaciones posibles de dos dados.
El cálculo de esas combinaciones nos la dá la función:
=PERMUTACIONES.A(6;2)
Vemos en la imagen el listado de esas 'permutaciones (con repetición)' así como el cálculo de la probabilidad de obtener cada suma desde 2 (1+1) hasta 12 (6+6)
Probabilidad Sumar 7 con dos dados

En el rango de celdas W4:W14 tenemos que la probabilidad al lanzar dos dados y sumen:
2 0,027777778
3 0,055555556
4 0,083333333
5 0,111111111
6 0,138888889
7 0,166666667
8 0,138888889
9 0,111111111
10 0,083333333
11 0,055555556
12 0,027777778

Nos interesa en este caso conocer la probabilidad de sumar siete, que es la más alta, con un valor del 16,6666%

Ese es el dato que devuelve el cálculo probabilístico...¿qué ocurrirá si sometemos el proceso a una simulación de Monte-Carlo?... Comprobémoslo.
En la celda D1 añadiremos el número de tiradas que queremos simular. 10.000 en mi primer ejemplo.
En B4 numeraremos la tirada, lo que nos servirá después para algunos de nuestros cálculos. Insertamos la función desbordada SECUENCIA:
=SECUENCIA(D1)
listará un vector desde 1 hasta 10.000

En C4 añadimos otra función desbordada MATRIZALEAT con la que obtendremos la simulación de los valores obtenidos con los dos dados:
=MATRIZALEAT(D1;2;1;6;VERDADERO)
lista una matriz de 10000 filas, 2 columnas, con valores enteros entre 1 y 6.

En E4 añadimos la suma de los dos dados:
=INDICE(C4#;B4#;1)+INDICE(C4#;B4#;2)

En F4 incluimos un conteo acumulado desde la primera tirada hasta la tirada N:
=CONTAR.SI(DESREF($E$4;;;B4#;1);7)
Con DESREF tenemos un rango variable que comienza siempre en E4 y llega hasta la fila de la tirada N.
Sobre ese rango variable aplicamos un CONTAR.SI que nos dice cuántas veces ha aparecido el 7 (de manera acumulada).

Finalmente en G4 añadimos la fórmula:
=F4#/B4#
donde tenemos el porcentaje de éxito (ha salido el 7) acumulado vivo...

Lo interesante de este ejemplo es el uso extensivo de funciones y fórmulas desbordadas, que nos permite automatizar cualquier cálculo de forma rápida modificando el valor de una celda (de D1).

Reflejemos esos valores sobre un gráfico de dispersión de líneas suavizadas y marcadores.
Para esto generaremos un gráfico desbordado (ver aquí).
Necesitamos crear dos nombres definidos con las siguientes fórmulas:
PorcConteo =DESREF(Hoja2!$G$4;;;Hoja2!$D$1;1)
Tirada =DESREF(Hoja2!$B$4;;;Hoja2!$D$1;1)

Insertamos el gráfico con la serie de datos: ='Hoja2'!PorConteo
Probabilidad Sumar 7 con dos dados

Y para las etiquetas: ='Hoja2'!Tirada
O incluso en este caso no sería necesario incluir...

En la celda G1 añado la fórmula: =DESREF(G4;D1-1;0) con la que obtenemos el último valor acumulado de la columna G (% conteo).
Y agregamos una nueva serie de datos al gráfico con este valor...
Probabilidad Sumar 7 con dos dados

Añadimos la etiqueta de datos a esta serie para ver el resultado en el gráfico.
Probabilidad Sumar 7 con dos dados


Se observa rápidamente la tendencia, según aumenta el número de tiradas, de la gráfica hacia aquel valor calculado de la probabilidad (0,166666)... pero sin llegar a la exactitud.
Nos puede valer como aproximación... o como demostración de la 'mano caprichosa' del azar ;-)

No hay comentarios:

Publicar un comentario

Nota: solo los miembros de este blog pueden publicar comentarios.