VBA: Latitud y Longitud de una dirección en Excel.

Hace unas semanas, buscando información sobre coordenadas geográficas de diferentes puntos, me encontré con una función personalizada en VBA (UDF) en la web www.policeanalyst.com que me pareció muy útil...
Por ese motivo me permito subirlo en el blog... con unos mínimos ajustes.

Se trata de una función que recupera los datos de Longitud y Latitud de cualquier dirección desde la herramienta de Google Maps, en su forma decimal.
Lo interesante de este dato es que a partir de la información recuperada, podremos plasmar diferentes datos sobre mapas dentro de nuestro Excel.. empleando herramientas como Power View, Mapas de Bing, etc...

Insertamos el código de la función en un módulo estándar de nuestro proyecto de VBA desde el editor de VB; sin olvidar de agregar la Referencia: Microsoft XML v6.0

Function GoogleGeoCode(address As String, coordenada As String) As Double
'Agregar la Referencia: Microsoft XML v6.0
Dim strAddress As String
Dim strQuery As String
Dim strLatitude As String
Dim strLongitude As String
'Nota: el parámeto 'coordenada' será el texto: 'Latitud' o 'Longitud'

'la función URLEncode transforma la dirección buscada
'en un literal para la búsqueda en Google...
strAddress = URLEncode(address)

'Montamos la cadena de texto par la consulta en el mapa de Google Maps
strQuery = "http://maps.googleapis.com/maps/api/geocode/xml?"
strQuery = strQuery & "address=" & strAddress
strQuery = strQuery & "&sensor=false"

'definimos los componentes XML and HTTP a emplear
Dim googleResult As New MSXML2.DOMDocument
Dim googleService As New MSXML2.XMLHTTP
Dim oNodes As MSXML2.IXMLDOMNodeList
Dim oNode As MSXML2.IXMLDOMNode

'Generamos la consulta en HTTP en la URL de Google...
'asegunrándonos del False para una operación síncrona
googleService.Open "GET", strQuery, False
googleService.send
googleResult.LoadXML (googleService.responseText)

Set oNodes = googleResult.getElementsByTagName("geometry")

'condicionamos la variable 'geometry' obtenida para recuperar
'nuestros parámetros: latitud y longitud
If oNodes.Length = 1 Then
    For Each oNode In oNodes
      strLatitude = oNode.ChildNodes(0).ChildNodes(0).Text
      strLongitude = oNode.ChildNodes(0).ChildNodes(1).Text
      
      If coordenada = "Latitud" Then
        GoogleGeoCode = (Val(Replace(strLatitude, ",", ".")))
      ElseIf coordenada = "Longitud" Then
        GoogleGeoCode = (Val(Replace(strLongitude, ",", ".")))
      End If
    Next oNode
Else
    GoogleGeoCode = Val(0)
End If
End Function
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function URLEncode(StringVal As String, Optional SpaceAsPlus As Boolean = False) As String
Dim StringLen As Long: StringLen = Len(StringVal)

If StringLen > 0 Then
ReDim result(StringLen) As String
Dim i As Long, CharCode As Integer
Dim Char As String, Space As String

If SpaceAsPlus Then Space = "+" Else Space = "%20"

For i = 1 To StringLen
  Char = Mid$(StringVal, i, 1)
  CharCode = Asc(Char)

  Select Case CharCode
  Case 97 To 122, 65 To 90, 48 To 57, 45, 46, 95, 126
    result(i) = Char
  Case 32
    result(i) = Space
  Case 0 To 15
    result(i) = "%0" & Hex(CharCode)
  Case Else
    result(i) = "%" & Hex(CharCode)
  End Select
Next i
URLEncode = Join(result, "")
End If
End Function

El resultado lo podemos ver en la imagen siguiente:

haz clic en la imagen

En el campo Latitud de nuestra Tabla hemos insertado la función:
=GoogleGeocode([@Estado];"Latitud")
y en el campo Longitud:
=GoogleGeocode([@Estado];"Longitud")