VBA: Adjuntar hoja activa como pdf al enviar un email desde Excel.

En varias ocasiones me han llegado consultas respecto a la manera de enviar Hojas de nuestros libros de trabajo en Excel como fichero adjunto al enviar nuestros correos...
En principio no es posible tal cosa, ya que Microsoft Outlook sólo permite adjuntar Libros completos... la solución más normal es generar un nuevo Libro y dentro de éste, copiar y pegar la Hoja a enviar.
Hoy haremos una operación algo distinta con una macro.
Generaremos un fichero .pdf temporalmente (luego borraremos como parte del procedimiento) con la hoja activa de nuestro libro, y será este .pdf el que adjuntaremos y enviaremos desde Outlook.

Para ello insertamos el código en un módulo estándar de nuestro proyecto de VBA desde el editor de VB.

Sub EnvioEmail_HojaActiva_comoPDF()
Dim olApp As Object
Dim olMail As Object
Dim RutaTemporal As String, NombreFicheroTemporal  As String, RutaCompleta As String

'deshabilitamos el refresco de pantalla
'y muy importante los eventos!
With Application
    .ScreenUpdating = False
    .EnableEvents = False
End With

'Definimos una variable que será la Ruta donde guardaremos,
'antes de enviar como adjunto, el pdf que generaremos...
RutaTemporal = Environ$("temp") & "\"

'Generamos el nombre del fichero temporal .Pdf
NombreFicheroTemporal = ActiveSheet.Name & ".pdf"

'Combinando las dos variables anteriores, tendremos la Ruta Completa de nuestro .pdf
RutaCompleta = RutaTemporal & NombreFicheroTemporal

'Depuramos posibles errores a la hora de Exportar
' a la ruta anterior, la hoja activa como PDF
On Error GoTo err
ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=RutaCompleta, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False

'LLega el momento de abrir la aplicación Outlook
Set olApp = CreateObject("Outlook.Application")
'y generar un nuevo email a enviar...
Set olMail = olApp.CreateItem(0)

Dim destinatario As String, Asunto As String, Cuerpo As String
'FALTA ASIGNAR VALORES A ESTAS VARIABLES!!!
On Error Resume Next
With olMail
    .to = destinatario          'añadimos el destinatario, el Para...
    '.CC = destinatario         'para adjuntar destinatario en Con Copia a...
    '.BCC = destinatario        'para adjuntar destinatario en Con Copia Oculta a...
    .Subject = Asunto        'indicaríamos el Asunto
    .Body = Cuerpo           'indicaríamos el Cuerpo del email
    'adjuntamos el fichero pdf desde la ruta donde la guardamos
    .Attachments.Add RutaCompleta
    .Display    'o bien usaremos .Send para enviar directamente...
    '.Send
End With
On Error GoTo 0

'Ya que el email ha sido enviado (o mostrado) con el pdf adjuntado
'podemos borrar el pdf que habíamos guardado (en la carpeta temporal)...
Kill RutaCompleta

'limpiamos las variables creadas.
Set olMail = Nothing
Set olApp = Nothing

'Reestablecemos las condiciones prevías
'refresco de pantalla y activamos loe eventos
With Application
    .ScreenUpdating = True
    .EnableEvents = True
End With

Exit Sub

'para el control de errores en caso de exportación como Pdf...
err:
    MsgBox err.Description

End Sub

Si ejecutamos nuestro procedimiento 'EnvioEmail_HojaActiva_comoPDF', veríamos:

Observa que al no haber asignado valor a las variables 'Destinatario, 'Asunto' y 'Cuerpo', en el email no han aparecido completados...