VBA: Copiar datos filtrados/visibles de una Tabla.

Veremos hoy un trabajo doble interesante:
Primero veremos cómo aplicar un filtro de fechas con macros sobre una Tabla (problemático habitualmente por una incompatibilidad de la configuración regional)
Segundo cómo copiar y pegar el resultado del filtro aplicado.

Partiremos de la siguiente hoja:

El trabajo del siguiente procedimiento consiste primero en aplicar un Filtro de fechas sobre el campo 'Fecha'; para ello deberemos tener la precaución de definir las variables con el tipo Long.
El motivo es salvar la configuración regional enfrentada de nuestra hoja de cálculo (dd/mm/aaaa) y la de VBA (mm/dd/yyyy)... al definirlo como Long (número entero), tratamos la fecha como lo que es para Excel, un número entero (en cualquier configuración regional, un número es un número...).

Una vez conseguido y aplicado el filtro, seleccionaremos sólo las celdas visible empleando el método SpecialCells(xlCellTypeVisible), a partir del cuerpo de la Tabla con la propiedad .DataBodyRange

Insertamos y ejecutamos el siguiente procedimiento, asignado al botón 'EXTRAER':

Sub RangoFecha()
'definimos las variables como Long para poder aplicar el autofiltro
'unica forma de salvar el problema de la configuración regional
Dim FechaDesde As Long, FechaHasta As Long
'definimos variables para aplicar el filtro sobre la tabla
FechaDesde = CDate(Range("B1").Value)
FechaHasta = CDate(Range("B2").Value)

'aplciamos el autofiltro sobre nuestro Tabla
ActiveSheet.ListObjects("TblDatos").Range.AutoFilter _
    Field:=1, Criteria1:=">=" & FechaDesde, Operator:=xlAnd, Criteria2:="<=" & FechaHasta

'aplciamos el copiado del resultado
Dim rng As Range

'trabajamos sólo sobre el cuerpo de la Tabla (.DataBodyRange)
'no sobre cabecera o fila totales
With ActiveSheet.ListObjects("TblDatos").DataBodyRange
    'definimos el rango visible
    'depurando el error por si no hubiera nada filtrado
    On Error Resume Next
    Set rng = .Resize(.Rows.Count, .Columns.Count).SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
End With

'controlamos el fallo..
If rng Is Nothing Then
    'si no hubiera nada como resultado del filtro
    MsgBox "Sin datos a copiar"
Else
    'en caso hubiera algún dato
    MsgBox rng.Address                      'mostramos el rango de celdas..
    rng.Copy Destination:=Range("C23")      'copiamos el rango y lo pegamos a partir de C23
    Application.CutCopyMode = False         'liberamos el Portapapeles
End If

'finalizamos quitando el filtro aplicado
ActiveSheet.ListObjects("TblDatos").Range.AutoFilter Field:=1

End Sub

El resultado tras la ejecución de la macro es el siguiente... Tras aplicar el filtro vemos el Cuadro de mensaje que muestra el rango de celdas visibles dentro del cuerpo de la Tabla

Y se continuamos la ejecución veremos el copiado y pegado de estos datos: