VBA: Obtener el color de relleno o fuente de una celda (con o sin formato condicional).

En varias ocasiones me han preguntado por la forma de determinar el color de relleno o de la fuente de una celda, en especial, cuando dicha celda tiene configurado un Formato condicional... obviamente, para determinar tal color (de relleno o de fuente) se necesita algo de programación.
El problema es que no existe una forma directa de obtener el color de una celda cuando lo que tiene aplicado es un Formato Condicional, ya que las propiedades estándar .Color o .ColorIndex sobre la celda de estudio no devuelve valor (o mejor dicho lo devuelve como sin color) cuando lo que tiene es un formato condicional aplicado.
Me puse a investigar y encontré esta Function que desarrolló Rick Rothstein, la cual adapté un poco y a la que he incorporado las explicaciones oportunas.

Fijémonos en la imagen:

donde las celdas B2 y B12 sólo tiene aplicado un formato de celda 'estándar', mientras que las celdas del rango B3:B11 tienen aplicado el siguiente formato condicional:

La función que crearemos está construida sobre tres argumentos (dos de ellos opcionales, pero predefinidos como VERDADERO); el primero será la celda (sólo UNA!!) que queremos analizar, el segundo conforma si obtendremos el color de relleno o de la fuente (según un valor Booleano - V ó F), y el tercer argumento define si emplearemos la propiedad .Color o .ColorIndex para conseguir el código del color de Fuente o Relleno (tmabién utilizando un valor Booleano).

En un módulo del editor de VB incluimos la siguiente Function:

Function ColorCelda(celda As Range, _
        Optional ColorRellenoCelda As Boolean = True, _
        Optional ReturnColorIndex As Long = True) As Long
' ColorRellenoCelda - Opcional, tipo Boolean (valor por defecto = TRUE)
'                VERDADERO hace que nuestra función nos devuelva el color de Relleno,
'                según la propiedad de .Color o .ColorIndex
'                determinada en el valor del tercer argumento ReturnColorIndex
'                FALSO  hace que nuestra función nos devuelva el color de la Fuente,
'                según la propiedad de .Color o .ColorIndex
' ReturnColorIndex - Opcional, tipo Boolean (valor por defecto = TRUE)
'                    VERDADERO hará que nuestra función emplee la propiedad .ColorIndex
'                    FALSO hará que nuestra función emplee la propiedad .Color

Dim X As Long
Dim Test As Boolean
Dim CeldaActiva As String

Application.Volatile

CeldaActiva = ActiveCell.Address
'recorremos todos los formatos condicionales existentes en la celda de estudio
For X = 1 To celda.FormatConditions.Count
  With celda.FormatConditions(X)
    'si la condición responde al Valor de una celda
    'sabiendo que .Formula1 y .Formula2 son los valores que podemos informar al configurar nuestro formato condicional
    If .Type = xlCellValue Then
      Select Case .Operator
        'Evaluate equivaldría a la función INDIRECTO de la hoja de cálculo
        'convierte, por tanto, un nombre de Microsoft Excel en un objeto, valor o referencia.
        Case xlBetween:      Test = celda.Value >= Evaluate(.Formula1) And celda.Value <= Evaluate(.Formula2)
        Case xlNotBetween:   Test = celda.Value <= Evaluate(.Formula1) Or celda.Value >= Evaluate(.Formula2)
        Case xlEqual:        Test = Evaluate(.Formula1) = celda.Value
        Case xlNotEqual:     Test = Evaluate(.Formula1) <> celda.Value
        Case xlGreater:      Test = celda.Value > Evaluate(.Formula1)
        Case xlLess:         Test = celda.Value < Evaluate(.Formula1)
        Case xlGreaterEqual: Test = celda.Value >= Evaluate(.Formula1)
        Case xlLessEqual:    Test = celda.Value <= Evaluate(.Formula1)
      End Select
    'si por contra la condición corresponde a una expresión o fórmula
    ElseIf .Type = xlExpression Then
      Application.ScreenUpdating = False
      celda.Select
      Test = Evaluate(.Formula1)
      Range(CeldaActiva).Select
      Application.ScreenUpdating = True
    End If

    'Verificamos nuestra comparativa Test, cuando sea VERDADERA
    If Test Then
      If ColorRellenoCelda Then
        'y además nuestro segundo y tercer argumento se han informado como CIERTOS
        'controlando el tercer argumento con la función VBA IIf
        ColorCelda = IIf(ReturnColorIndex, .Interior.ColorIndex, .Interior.Color)
      Else
        'pero si nuestro segundo argumento es FALSO y el tercer argumento se ha informado como CIERTO
        'controlando el tercer argumento con la función VBA IIf
        ColorCelda = IIf(ReturnColorIndex, .Font.ColorIndex, .Font.Color)
      End If
      'salimos de la función...
      Exit Function
    End If
  End With
Next
  
'si no tuviera Formato condicional aplicado...
If ColorRellenoCelda Then
  'y si hubieramos indicado como CIERTO el segundo argumento
  ColorCelda = IIf(ReturnColorIndex, celda.Interior.ColorIndex, celda.Interior.Color)
Else
  'y si hubieramos indicado como FALSO el segundo argumento
  ColorCelda = IIf(ReturnColorIndex, celda.Font.ColorIndex, celda.Font.Color)
End If
End Function

De especial interés en esta Function es el empleo que se hace de la propiedad .Type del formato condicional (.FormatConditions(i).Type), con el que averigüamos o controlamos el tipo de Formato Condicional de la celda analizada.
Especifica si el formato condicional está basado en el valor de una celda.
Nombre Valor Descripción
xlCellValue --- 1 --- Valor de celda
xlExpression --- 2 --- Expresión
xlColorScale --- 3 --- Escala de colores
xlDatabar --- 4 --- Barra de datos
xlTop10 --- 5 --- 10 valores más frecuentes
XlIconSet --- 6 --- Conjunto de iconos
xlUniqueValues --- 8 --- Valores únicos
xlTextString --- 9 --- Cadena de texto
xlBlanksCondition --- 10 --- Condición de celdas que están en blanco
xlTimePeriod --- 11 --- Período de tiempo
xlAboveAverageCondition --- 12 --- Condición por encima de la media
xlNoBlanksCondition --- 13 --- Condición de celdas que no están en blanco
xlErrorsCondition --- 16 --- Condición de errores
xlNoErrorsCondition --- 17 --- Condición sin errores
Es decir, si se trata de un Formato condional asociado al Valor de la celda:

O bien un Formato condicional basado en una expresión o fórmula:

Una vez chequeado si la celda cumple alguna de los criterios de los formatos condicionales, en caso afirmativo, con la funicón VBA IIf dirigimos nuestra function ColorCelda hacia la propiedad .Color o .ColorIndex; que de una manera directa tendría la forma:
celda.FormatConditions(X).Interior.ColorIndex
La Function 'ColorCelda' finaliza controlando el caso en que en la celda de estudio no hay aplicado formato condicional...