sábado, 22 de octubre de 2011

BUSCARV como argumento en una función SI.

Habitualmente trabajamos con la función BUSCARV pensando sólo en búsquedas verticales, olvidando otros usos o utilidades; en este ejemplo de hoy veremos como nos aprovecharemos de ésta, para anidarla en una función SI condicional, como parte de la prueba lógica.
En el ejemplo que trataré hoy buscaremos una respuesta al siguiente problema. Si partimos de una tabla donde vemos para diferentes elementos qué meses están operativos, en concreto tenemos un listado de cruceros y el intervalo de meses entre los cuales, dicho crucero, está operativo; para un listado de posibles reservas atendiendo a un crucero determinado y a una fecha de embarque, tendremos que obtener una SI o un NO que determine si para dicha Fecha y Crucero tal reserva es posible.
Vemos nuestras tablas de trabajo:


haz click en la imagen


La finalidad es combinar ambos requisitos solicitados en una única prueba lógica de nuestra función condicional SI, de tal forma que devuelva un SI o un NO si se verificase o no.
Debemos construir un condición que nos diga si para un Crucero concreto la fecha de reserva propuesta cumple o está dentro del intervalo de meses definido (rango E2:G5).
Esto lo conseguiremos incluyendo la función Y como prueba lógica, de tal forma que en esta unimos dos de las condiciones a cumplir, para cada Fecha de reserva sea mayor o igual que el primer mes de inicio de operaciones y que sea menor o igual que el último mes operativo del crucero:
Y(Fecha reserva>=Fecha inicio operaciones; Fecha reserva<=Fecha fin operaciones)
Como estamos trabajando con meses, trataremos los datos con la función MES.
La clave, en todo caso de esto, es determinar correctamente cuál es la Fecha de inicio y fin de operaciones para cada Crucero a reservar. Esto lo conseguiremos con la función BUSCARV, siendo las condiciones finales:
MES(Fecha reserva)>=BUSCARV(Crucero;$E$2:$G$5;2;0)
MES(Fecha reserva)<=BUSCARV(Crucero;$E$2:$G$5;3;0)
todo unido en una sóla función, y tomando las celdas a evaluar para el primer registro, tenemos la siguiente Prueba lógica:
Y(MES(B2)>=BUSCARV(A2;$E$2:$G$5;2;0);MES(B2)<=BUSCARV(A2;$E$2:$G$5;3;0))


haz click en la imagen


Podemos analizar nuestra función completa:
=SI(Y(MES(B2)>=BUSCARV(A2;$E$2:$G$5;2;0);MES(B2)<=BUSCARV(A2;$E$2:$G$5;3;0));"SI";"NO")
y comprobar como se verifica que con BUSCARV encontramos cuales son los meses inicial y final de operatividad del crucero concreto que estamos evaluando, para luego comprobar si la Fecha de reserva o salida se encuentra dentro de dicho intervalo de meses.
Para el primer registro, evaluamos el crucero 'Princesa del amanecer', para una Fecha de reserva o salida 10-junio-2011, esto es MES = 6, con la fórmula evaluamos si el 'Princesa del amanecer' opera en junio, y que como podemos comprobar sólo lo hace entre agosto (8) y septiembre (9), por lo que el resultado de nuestra función no podía ser otro que NO.

119 comentarios:

  1. =SI(Y(MES(B2)>=INDICE($E$2:$G$4,COINCIDIR(A2,$E$2:$E$4,0),2),MES(B2)<=INDICE($E$2:$G$4,COINCIDIR(A2,$E$2:$E$4,0),3)),"SI","NO")

    Aqui te mando otra solucion factible

    ResponderEliminar
  2. Correcto, la base es la misma, en tu ejemplo en lugar de BUSCARV empleas INDICE.
    Muchas gracias por tu aporte!!

    Slds

    ResponderEliminar
  3. hola Ismael. mi pregunta es la siguiente: tengo Tabla1 campos: ID, Asegurador, medico, Operador. De estos 4 campos el unico que tiene valores es ID, los otros 3 estan vacios.
    Tabla2 campos: ID, nombre, rol. estos tres campos tienen informacion.
    ID: 12,23,46,51 etc
    nombre: total eps,ramiro muñoz, farmacien,Meredi, etc
    rol: Asegurador, medico,Operador. uno para cada nombre, cada id de la Tabla1 debe tener estos 3 campos.
    Necesito llenar los campos 3 campos vacios de la tabla 1 con los de la tabla 2 pero no pude con la funcion buscarv, incluso utilice la funcion SI con un buscarv anidado pero tampoco me trae toda la informacion
    agradezco inmensamente tu colaboracion

    ResponderEliminar
    Respuestas
    1. Hola Guillermo,
      por confirmar, entiendo que neceistas llevar el nombre de la Tabla2, en base al rol (asegurdor, médico, operador) al campo correspondiente de la Tabla1, según su Id.
      Si es así, y enentiendo que trabajas con Tablas (llamadas Tabla1 y Tabla2 con las cabeceras que has indicado), entonces para el campo 'Asegurador' de la Tabla1 añade la fórmula:
      =SI(BUSCARV([@id];Tabla2;3;0)=Tabla1[[#Encabezados];[Asegurador]];BUSCARV([@id];Tabla2;2;0);"")

      para el campo 'Médico'
      =SI(BUSCARV([@id];Tabla2;3;0)=Tabla1[[#Encabezados];[Médico]];BUSCARV([@id];Tabla2;2;0);"")

      y para el campo 'Operador'
      =SI(BUSCARV([@id];Tabla2;3;0)=Tabla1[[#Encabezados];[operador]];BUSCARV([@id];Tabla2;2;0);"")

      Espero te sirva.
      Slds cordiales

      Eliminar
    2. Ismael, gracias por tu colaboracion, realice los ajustes segun mis archivos y la formula finalmente quedo asi: =SI(BUSCARV(B2;[Libro7]Hoja1!$B$2:$I$40017;8;0)="Asegurador";BUSCARV(Tabla1!B2;[Libro7]Hoja1!aseguradores al campo Asegurador, pero me ha costado cuando $B$2:$G$40017;6;0);"")
      pero tengo un problema, efectivamente me trae todos los la ejecuto en Operador Logistico y en Médico Tratante. He actualizado todos los campos de la formula y aún asi no lo consigo. te copio la de Operador logistico tambien:
      =SI(BUSCARV(B2;[Libro7]Hoja1!$B$2:$I$40017;8;0)="Operador Logistico";BUSCARV(B2;[Libro7]Hoja1!$B$2:$G$40017;6;0);"")
      gracias por tu colaboracion

      Eliminar
    3. Hola Guillermo,
      a simple vista diría que la fórmula es correcta.
      Asegúrate que el valor de B2 se halla en la primera columna del rango [Libro7]Hoja1!$B$2:$I$40017, y que el valor correspondiente devuelto de la columna 8 (columna I) está igual escrito que los valores buscados (Asegurador, Operador logístico o Médico Tratante), con acentos, etc...

      No puedo decirte más...las fórmulas que te envié están probadas y funcionan bien, y si adem´s por loque comentas sólo te falla en ese caso, claramente el fallo debe estár en algo del texto.

      Slds

      Eliminar
  4. Ismael. Muchas gracias por tu invaluable colaboracion.

    ResponderEliminar
  5. Buenas noches
    me podrían ayudar con este caso, he intentado índice con la función de coincidir, pero me da de resultado valor.

    Intento obtener el precio del código pero que coincida con la factura.

    A B C
    1 factura codigo parte precio
    2 80410954 DG93F11215BE 185.325
    3 80410953 DG93F11215BE 185.325
    4
    5
    6 80410953
    7 DG93F11215BE

    INDICE(PRECIO,COINCIDIR(A6&A7,A2;A3&B2:B3,0))

    ResponderEliminar
    Respuestas
    1. Hola Erika,
      el problema es cómo has contruido la función coincidir y que además debes validarla matricialmente (es decir, presionando Ctrl+Mayus+Enter en lugar de Enter).
      Prueba sobre tu ejemplo la siguiente fórmula:
      =INDICE(C2:C4;COINCIDIR($A$6&$A$7;A2:A4&B2:B4;0))

      Espero te sirva.
      Slds

      Eliminar
  6. Buenas noches si quiero una formula donde tengo dos filas =si b5=f5 que conserve su valor y si no es el mismo se quede en blanco pero tambien que busque donde seria su posicion como seria

    ResponderEliminar
    Respuestas
    1. Hola Luz,
      podría ser
      =SI(B5=F5;B5;"")
      y luego arrastrar o copiar y pegar la fórmula al resto.
      Para encontrar su posición podrías emplear la función COINCIDIR...
      Saludos

      Eliminar
  7. Tengo que buscar un código, si lo encuentra, que develva la cantidad de stock de la comunna B, si el codigo no esta que devuelva el valor "0"
    que funcion puedo usar?

    saludos

    ResponderEliminar
    Respuestas
    1. Hola que tal?
      podrías usar una combinación:
      =SI.ERROR(BUSCARV(código;B:B;1;0);"0")

      siendo código la celda con el código de la película a buscar...
      Saludos

      Eliminar
  8. HOLA
    BUSCO AYUDA ESPERO Y ME PUEDAN APOYAR
    TENGO UNA BD DONDE TENGO VARIOS REGISTROS
    1 ADFSADF
    1 XCVBCVB
    1 ASDF
    1 QWE
    2 GFEF
    2 FRWER
    2 SDFGD
    ....

    LO QUE QUIERO ES HACER UNA BUSQUEDA DONDE ME ENCUENTRE TODOS LOS NUMEROS 1 CON SU CORRESPONDIENTE INFORMACION

    ESPERO ME HAYA DADO A EXPLICAR

    SALUDOS!!

    ResponderEliminar
    Respuestas
    1. Hola Joel,
      para estos casos de búsqueda múltiple, lo más sencillo es construir una tabla dinámica, llevando el campo número y descripción al área de filas... para luego filtrar por el campo número y mostrar el valor deseado.

      Saludos

      Eliminar
  9. Hola:
    Necesitaría ayuda con este ejemplo:

    Tengo una tabla con varias preguntas y cada una con 4 respuestas.
    Deseo que cuando marque una de ellas (a, b, c, ó d) me devuelva el valor que hay donde se encuentran el número de pregunta que está en las filas (1, 2, 3, ...) y en las columnas donde tengo las respuestas (a,b,c,d)


    Que te gusta más
    a la pera
    b la manzana
    c la sandía
    d el melón

    Elije tu destino
    a París
    b Roma
    c Londres
    d Madrid

    En esta tabla está el valor que quiero que me devuelva cuando marco una respuesta:

    P a b c d
    1 K A R V
    2 V A R K
    3 K V R A
    4 K A V R

    Es decir:
    si marco de la pregunta 1 la opción a me devuelve K
    si marco de la pregunta 3 la opción d me decuelve A

    No sé si me he explicado
    Gracias!!!

    ResponderEliminar
    Respuestas
    1. Hola Javier,
      supondré que las preguntas están numeradas.. en ese caso podrías aplicar un BUSCARH sobre la tabla de respuestas:
      BUSCARH(respuesta (A.b.c.d);TablaRespuestas;COINCIDIR(NumPregunta;PrimeraColumnaTablaRespuestas;0);0)

      Espero te oriente.. es difícil sin tener referencias de celdas.
      Saludos

      Eliminar
    2. Muchas gracias por la respuesta Ismael:

      Lo tenía también con BUSCARH, aunque la fórmula no era tan buena y que cambiaré
      Mi problema es el condicional con una casilla de verificación

      Es decir: Colocar una casilla de verificación de tal manera que al activarla me haga ese BUSCARH

      Muchas gracias de nuevo
      Un saludo

      Eliminar
  10. hola tengo un ejercicio donde debo sacar un valor de una matriz mxn; m=tipo de producto y n= referencia, si se sabe el tipo de producto y la referencia
    A B C D
    X 10 15 8 3
    Y 5 2 1 20
    Z 3 5 6 12

    se desea que arroje el valor 2 si donde voy a hacer el llamado escribo B,Y

    ResponderEliminar
    Respuestas
    1. Hola Camilo,
      lo habitual es emplear una combinación de las funciones INDICE+COINCIDIR, algo así:
      =INDICE(A2:D4;COINCIDIR("Y";A2:A4;0);COINCIDIR("B";B1:D1;0))

      Saludos

      Eliminar
  11. Hola Ismael me puedes ayudar con una consulta en Excel, la verdad no he podido organizar dicha información,
    mil gracias si me colaboras con tu tiempo

    ResponderEliminar
  12. Empleado Hora
    Arias Maturana Orlay 07:57:15
    Arias Maturana Orlay 12:52:33
    Arias Maturana Orlay 14:20:43
    Castro Olave Mauricio 07:01:39
    Castro Olave Mauricio 11:53:38
    Cordoba Garrido Argelis 08:08:32
    Cordoba Garrido Argelis 14:12:37

    Actualmente lo hago manual, si de pronto hay alguna forma automática que me lo organice seria de mucha ayuda

    Empleado ENTRADA SAL/DIA ENTR/TARDE SAL/NO
    Arias Maturana Orlay 07:57:15 12:52:33 14:20:43 --
    Castro Olave Mauricio 07:01:39 11:53:38 -- --
    Cordoba Garrido Argelis 08:08:32 -- 14:12:37 --

    Pienso que es con BUSCARV pero no se como condicionar la hora
    mil gracias

    ResponderEliminar
    Respuestas
    1. Hola Leonid,
      te recomendaría crearas una tabla dinámica, llevando el campo Empleado al área de filas, el campo (a crear) Tipo entrada / Salida al área de columnas y el campo Hora al área de Valores.

      Empleado Hora
      Arias Maturana Orlay 07:57:15 Entrada
      Arias Maturana Orlay 12:52:33 Salida día
      Arias Maturana Orlay 14:20:43 Entrada Tarde
      Castro Olave Mauricio 07:01:39 Entrada
      Castro Olave Mauricio 11:53:38 Salida día
      Cordoba Garrido Argelis 08:08:32 Entrada
      Cordoba Garrido Argelis 14:12:37 Entrada Tarde

      Espero te sirva.
      Saludos

      Eliminar
  13. Buenas tardes, agradezco si alguien me puede colaborar con este tema, debo programar un liquidador de precios, tengo en una hoja las diferentes listas de precios para diferentes Puntos de Venta, la idea es que yo seleccione el punto de venta y teniendo el código del producto me traiga el precio del producto de ese punto de venta... gracias

    ResponderEliminar
    Respuestas
    1. Hola,
      prueba empleando la función BUSCARV buscando el Punto de venta en la lista de precios...

      Espero te de la idea

      Saludos

      Eliminar
  14. Julian veo que el problema que planteas tiene dos criterios, uno es el punto de venta y el otro es el codigo, creo que podria ayudarte para la solcuion de tu problema la funcion suma producto.

    En esta funcion puedes declaran las dos condiciones y pones el rango de suma, me supongo que las listas solo hay un solo precio para cada punto de venta, es decir no essta repetido. por lo que si funcionaria la funciion que te comento

    SumaProducto((A1:a100=punto_Venta)*(B1:b100=Codigo)*(D2:D100))

    Algo como esto quedaria la funcion.

    ResponderEliminar
    Respuestas
    1. Gracias Gilberto,
      correcto ;-)
      se me pasó al leer la segunda condición...
      Saludos y gracias por el aporte

      Eliminar
    2. hola no creo que sea tan sencillo, explico un poco mas: en un mismo archivo tengo una hoja llamada listas que contiene 10 listas de precios y otra hoja llamada liquidador de pedidos, los códigos son los mismos tanto en las listas como en el formato de pedidos, pero necesito que al seleccionar la lista de precios, mediante el código me traiga el precio por bulto del producto.

      Eliminar
    3. Opino que la opción aportada por Gilberto es la adecuada..

      otras opciones de búsqueda podría ser con la función BUSCARV y ELEGIR, donde poder indicar el producto buscado y en qué lista...

      Eliminar
  15. Gracias Ismael es un placer poder contribuir...

    Julian.
    Cuando te refieres a 10 listas quieres decir que cada lista es independiente, es decir una lista abarca del rango A1:C100 y la otra lista de D2:D100 y así sucesivamente.
    O estas refiriéndote a listas desplegables en las que si seleccionas un item de la lista esta se debe tomar como criterio junto con el código para que se busque el precio.

    No se si por aqui se pueden subir archivos, me parece que seria de mucha ayuda para ver con mas claridad el problema que planteas.


    ResponderEliminar
  16. Estimados
    Agradecería su ayuda en crear una formula según las siguientes condiciones
    Tengo una orden de compra hecha en enero 2016 por $12.000.000, su condición de pago a 30-60-90 y 120 días, es decir de febrero a mayo debo pagar $5.000.000 respectivamente, pero necesito que cada pago quede reflejado en una celda distinta según su mes de pago.

    La idea es poder tener el resultado como fórmula ya que tengo en promedio 30.000 filas mensuales con esa misma estructura.
    Desde ya muy agradecido
    Alejandro
    ale.toro@gmail.com

    ResponderEliminar
    Respuestas
    1. Hola Alejandro,
      tendrías que condicionar las diferentes columnas, con los meses, y compararlos con los vencimientos de cada orden de compra...
      es decir, según la fecha de compra en cada columna añadir un condicional para saber si en esa columna (mes) debe caer la parte proporcional...
      Intentaré subir una exposición al blog.
      Saludos

      Eliminar
    2. Excelente, muchas gracias Ismael

      Eliminar
  17. hola amigos
    agradecería su ayuda lo que quiero es poder ingresar información en una tabla ya existente, teniendo que digitar solamente el código y la cantidad, y que me lo guarde en la celda correspondiente según el código digitado.
    de antemano gracias

    ResponderEliminar
    Respuestas
    1. Hola Wilfredo,
      si trabajas sobre una Tabla con algunas fórmulas, por ejemplo de BUSCARV que recuperen datos de otro origen, y para completar información rellenas datos con el Formulario de datos tendrás lo que parece necesitas
      http://excelforo.blogspot.com.es/2010/04/un-formulario-de-datos-en-excel.html
      Saludos

      Eliminar
  18. Este comentario ha sido eliminado por el autor.

    ResponderEliminar
  19. Gracias Ismael por tomarte el tiempo para responderme, sin embargo lo que sucede es que estos formularios agregan un nuevo registro y yo lo que necesito es agregar un dato a los registros existentes, te lo explico con un ejemplo:

    código nombre abono 1 abono2 abono3
    001 Pedro Ramos $ 25.00 $ 32.00
    002 Juan Perez $ 17.00 $ 16.00

    si tuviera 100 o mas códigos es tedioso buscar el código de la persona su nombre y digitar la cantidad en su registro, mi idea seria un formulario o algo así que yo solo digite el código y la cantidad y automática mente se guarde en la columna correspondiente del registro de cada persona, mi conocimiento de Excel es limitado por eso recurro a uds. ya que he leído mucho en este foro y ayudan mucho a personas con dificultades
    Felicitaciones por su trabajo en este foro y bendiciones.

    ResponderEliminar
    Respuestas
    1. Hola Wilfredo,
      realmente con ese formulario estándar de Excel también puedes realizar búsquedas múltiples, según varios criterios.. y una vez localizado modificar el resto de los campos de dicho registro (todo además de insertar nuevos registros).
      Fíjate que en la explicación donde dice:
      'Esta herramienta nos ofece además la posibilidad de filtrar registros de nuestra base de datos pulsando el botón de Criterios, utilizado sobre los diferentes campos editables habilitados, combinando los distintos comodines (* ó ?).'
      Es decir, escribiendo en los campos vacíos las condiciones de búsqueda localizas el registro en cuestión.

      Otras opciones pasan por aplicar un Autofiltro y sobre el los diferentes criterios...

      O, por supuesto, realizar un desarrollo personalizado con un UserForm y programación...

      Te recomendaría las primeras opciones.
      Saludos

      Eliminar
  20. Excelente Ismael, nuevamente gracias por tu respuesta. Bendiciones para todos ustedes.

    ResponderEliminar
  21. Estimados, una pregunta. Si deseo.buscar un dato especifico en.una matriz y resulta que en.la.dicha.no se halla, como puedo colocar una condición para que, en caso de no localizar el dato se busque en.otra matriz del mismo documento? Agradeceré su apoyo.

    ResponderEliminar
    Respuestas
    1. Hola Ruben,
      podrías anidar tu búsqueda en un SI.ERROR para dirigir otra búsqueda a otra matriz:
      =SI.ERROR(busqueda1;busqueda2)
      Saludos

      Eliminar
  22. Gracias Ismael, en efecto funciona!

    ResponderEliminar
  23. si deseo buscar un valor superior a una fecha. por ejemplo 02-04-16 deseo buscar valores superiores a esa fecha con buscarV

    ResponderEliminar
    Respuestas
    1. Hola Ángel,
      que tal estás?, un placer saludarte igualmente.
      Habría que entender el contexto.. pero quizá construyendo tu BUSCARV con el cuarto argumento como VERDADERO te pudiera servir...
      Saludos cordiales

      Eliminar
  24. Hola necesito ayuda para resolver esta formula;Lo intentado en varias ocasiones, He colocado ¨Y¨ y ¨O¨pero no tengo solucion

    A) Si el Boleto es Mayor 500 y Menor igual a 675, paga Boleto por 8%
    B) Si la Aerolínea es igual a TACA o es igual a LACSA, paga Boleto por 5%
    C) Los demás pagan Boleto por 3%(3 puntos…. 1.5 cada condicional)

    ResponderEliminar
    Respuestas
    1. Hola,
      podría ser algo así:
      =SI(Y(boleto>500;boleto<=675);boleto*8%;SI(O(aerolinea="TACA";aerolinea="LACSA");boleto*5%;boleto*3%))

      Saludos

      Eliminar
  25. Estimados requiero hacer lo siguiente;

    Necesito realizar un programa de mantención por lo que cuando esta en cierto rango de horas la celda que continua me avisa que hay que programar la mantención, luego de esto viene la celda que dice si la mantención esta pendiente; programada o realizada.
    Necesito la función para que la celda que avisa que hay que programar la mantención busque si esta mantención fue realizada y si es así que deje la celda en blanco.

    Gracias.

    ResponderEliminar
    Respuestas
    1. Hola Sebastián,
      parece necesitaras aplicar una función condicional del tipo
      =SI(Y(hora1<=HoraActual;HoraActual<=hora2);"programar la mantención")
      y con un segundo condicional evaluar si está pendiente programada o realizada.

      Al desconocer tu modelo de trabajo es complicado ajustar más...
      pero la idea es esa.
      Slds

      Eliminar
  26. Buen día le realizo la siguiente consulta, tengo que clasificar mis registros en filas en tres categorías (A, B o C). Cada categoría contiene restricciones de la siguiente manera: para ser A la acidez debe ser mayor a 5,8; el contenido de azucares debe estar entre 1 y 5; la elasticidad debe ser menor de 4 y el color debe estar entre 30 y 38. Para ser categoría B la acidez debe ser mayor a 5,8; el contenido de azucares puede ser cualquiera; la elasticidad debe estar entre 4 y 5 y el color debe estar entre 30 y 43. Y para sería categoría C si no se cumple ninguna de las anteriores. Le agradecería la ayuda, mi tabla tiene la siguiente forma:
    Muestra Acidez Azúcar Elasticidad Color
    1 5,8 2 3,0 32
    2 5,7 3 4,5 40
    3 6,0 6 6,0 35
    4 5,6 1 4,0 30

    ResponderEliminar
    Respuestas
    1. Hola,
      podría ser:
      =SI(Y(B10>5,8;C10>1;C10<5;D10<4;E10>30;E10<38);"a";SI(Y(B10>5,8;D10>4;D10<5;E10>30;E10<43);"b";"c"))

      Espero te de la idea
      Saludos

      Eliminar
  27. buena tarde tengo la sig consulta, tengo un listado de personas y las fechas en compras que realizaron, lo que quiero en ver que funcion ocupo para que me busque el numbre de una persona determinada y me sume lo consumido en el mes

    ResponderEliminar
    Respuestas
    1. Hola Carlos,
      si sabes qué Nombre y que mes es el que necesitas, puedes aplicar la función SUMAR.SI.CONJUNTO(rng_suma;rng_nombres;NOMBRE;rng_fechas;">="&Fecha1;rng_fechas;"<="&Fecha2)

      Slds

      Eliminar
  28. Buen día.
    Tengo unas inquietudes frente a unos datos, tengo dos cuadros con información (materiales) organizados de la siguiente manera:
    1. Despiece:
    Columna A: código; columna B: descripción; columna C: consumo.
    2. Precios:
    Columna A: código; columna B: descripción; columna C: precio; columna D: proveedor.
    Existe el caso que para un mismo código haya diferentes proveedores.

    Las inquietudes radican en como modificar la formula buscar
    1. Para que me muestre las diferentes opciones de proveedores para un mismo código, en diferentes celdas.
    2. Que me muestre el precio de acuerdo al código y proveedor. Para esto e utilizado buscar con coincidencia, pero me arroja error: =BUSCARV(A4;CONSOLIDADO!A:E;COINCIDIR('AMBU-MASTER'!F4;CONSOLIDADO!A:E;0);VERDADERO).

    Agradezco mucho tu colaboración.

    ResponderEliminar
    Respuestas
    1. aclaro, que un proveedor también tiene asignado diferentes códigos.

      Eliminar
    2. Hola Leydi Lizet,
      te aclaro que con funciones como BUSCARV únicamente obtendras un valor, que será la primera coincidencia...

      Por otra parte permíteme un consejo en cuanto a tu función:
      =BUSCARV(A4;CONSOLIDADO!A1:E1000;COINCIDIR('AMBU-MASTER'!F4;CONSOLIDADO!A1:E1;0);falso)
      es decir, acota la búsqueda al rango exacto (o mejor trabaja sobre tablas).
      COINCIDIR debes emplearlo sobre una fila o columna
      Con BUSCARV emplea FALSO en vez de VERDADERO para forzar una búsqueda exacta (y no aproximada)

      Saludos

      Eliminar
  29. Buen día, agradezco su ayuda para crear una formula para comparar dos hojas de empleados, donde una hoja es la base de datos completa y la otra hoja son los datos únicamente de los empleados activos. La idea es que en la hoja base de datos haya una columna con el concepto Activo y Retirado.
    Agradezco mucho su ayuda.

    ResponderEliminar
    Respuestas
    1. Hola Andrea,
      en la BD completa:
      =SI(ESERROR(BUSCARV(Empleado;TablaActivos;1;0));"Retirado";"Activo")
      Saludos

      Eliminar
  30. buenas noches, mi duda es que tengo un formulario y una tabla de datos, del formulario tomo el código para buscar en la tabla de datos y deseo que copie un valor a la tabla desde el mismo formulario al la celda donde introduzco la formula. espero y me puedan ayudar...

    ResponderEliminar
    Respuestas
    1. Hola Antonio,
      entiendo hablamos de un UserForm con TextBox, etc..
      Para trasladar datos del formulario a la hoja basta algo similar a:
      range("A1").value = TextBox1.Value

      obviamente a la celda de la hoja de cálculo que sea y tomando el nombre del TextBox, ComboBox, etc que le hayas puesto.

      Saludos

      Eliminar
  31. Buenos días!!
    Necesito ayuda en lo siguiente: necesito traerme a un cuadro con BuscarV el monto del gasto real por centro de costo de varias cuentas contables, la condición seria que si en ambos archivos el centro de costo coincide entonces me traiga el valor que le corresponde a la cuenta buscada.
    Espero pueda ayudarme. Agradecida.

    ResponderEliminar
    Respuestas
    1. Hola Alejandra,
      como tu misma indicas parece que BUSCARV es la función adecuada...
      Sin ver la distribución de datos es difícil darte la fórmula exacta.
      Pero la idea es:
      =BUSCARV(centro_costo;Tabla_con cuentas_contables;num_columna_monto_real;FALSO)

      Slds

      Eliminar
  32. HOLA ME PUEDES AYUDAR POR FAVOR. GRACIAS...
    Mediante el uso de la función BUSCARV , resolver de descuento
    Para los montos crediticios de 0 hasta 20,000.00 el descuento será del 5% del monto
    Para los montos crediticios hasta 24,000.00 el descuento será del 3% del monto
    Para los montos crediticios hasta 60,000.00 el descuento será del 2% del monto
    Para los montos crediticios que superen los 60,000.00 el descuento será del 1% del monto.
    NUMCLI Cliente Monto crediticio DESCUENTOS
    1 Cliente01 20,222.00
    2 Cliente02 28,283.00
    3 Cliente03 49,605.00
    4 Cliente04 32,733.00
    5 Cliente05 17,228.00
    6 Cliente06 37,939.00
    7 Cliente07 22,517.00
    8 Cliente08 30,107.00
    9 Cliente09 20,797.00
    10 Cliente10 10,912.00
    11 Cliente11 25,620.00
    12 Cliente12 23,925.00
    13 Cliente13 21,144.00
    14 Cliente14 43,460.00
    15 Cliente15 18,578.00
    16 Cliente16 24,028.00
    17 Cliente17 49,907.00
    18 Cliente18 15,129.00
    19 Cliente19 27,561.00
    20 Cliente20 19,573.00
    21 Cliente21 49,100.00
    22 Cliente22 15,954.00
    23 Cliente23 45,839.00
    24 Cliente24 24,904.00
    25 Cliente25 19,293.00
    26 Cliente26 29,196.00
    27 Cliente27 28,034.00
    28 Cliente28 43,529.00
    29 Cliente29 36,484.00
    30 Cliente30 34,727.00
    31 Cliente31 37,653.00


    ResponderEliminar
    Respuestas
    1. Hola Janet,
      dispones la siguiente tabla en A1:B4
      0 20000 5%
      20000 24000 3%
      24000 60000 2%
      60000 1%

      luego en tu tabla, debajo de la columna de DESCUENTOS:
      =buscarv(Celda_Monto;$A$1:$B$4;3;1)

      Saludos

      Eliminar
  33. Hola buenas tardes quisiera pedir tu ayuda para este caso:

    en la fila 1, tengo fechas el mismo dia cada 2 columas, en la la fila 2 tengo el numero 1 y 2 (turno 1 y 2)
    y en la fila 3, la producción del dia

    ej.
    01/feb 01/feb 02/feb 02/feb 03/feb 03/feb
    1 2 1 2 1 2
    PERA LIMON LIMON PERA UVA LIMON

    LO QUE QUIERO HACER ES PONER UNA FORMULA QUE YO INDCADONLE EL DIA Y EL TURNO ME DIGA QUE FRUTA SE PRODUJO

    DIA: 03/Feb
    TURNO: 2
    FRUTA______ (QUE FORMULA PONGO)

    Espero me puedas ayudar! te agradezco mucho de antemano!

    ResponderEliminar
    Respuestas
    1. Hola Gaby,
      suponiendo los datos en A1:F3, y los datos a formular en:
      Fecha en B6
      Turno en B7
      la fórmula en B8 sería:
      =INDICE(A3:F3;1;COINCIDIR(B6;A1:F1;0)+B7-1)

      Saludos

      Eliminar
    2. Muchas gracias por tu apoyo, jamas hubiera dado con esa formula sin tu ayuda!
      muchas gracias!

      Eliminar
  34. Hola, me podrias ayudar, please.

    Tengo una base de datos de renta y venta de equipo.
    Tengo una columna "operacion" donde especifico si es "renta" o "venta". Y otras 4 columnas "tenedor", "cuchara", "cuchillo", "plato". donde se menciona la cantidad a vender o rentar, 10,20,30 etc.

    En otra columna tengo "subtotal" donde me gustaria que apareciera el total a pagar.

    Tengo en la hoja 2 una lista de precios de venta columna A producto y B precio y tengo otra hoja con una lista de precios de renta igual columna A producto y B producto.

    Como puedo hacer para que en la columna de subtotal.
    1. Decirle que SI, es renta se vaya a la lista de precios de renta y multiplique el total del equipo digamos 10 tenedores x el precio de renta $2.00 c/u + 20 cuchillos x su respectivo precio + las cucharas x su precio etc etc.

    2. Y que si en la columna de operacion dice "venta" vaya a la lista de precios de venta y multiplique la cantidad de tenedores vendidos x su precio unitario, igual cucharas y cuchillos y lo sume todo. Para saber el subtotal a pagar.

    Muchas gracias de antamano.

    ResponderEliminar
    Respuestas
    1. Hola Karma,
      tendrías que aplicar (para cada columna: "tenedor", "cuchara", "cuchillo", "plato") un condicional sobre el tipo de operación:
      =SI(operacion="VENTA", BUSCARV("tenedor";TablaPreciosVenta;2;0);BUSCARV("tenedor";TablaPreciosAlquiler;2;0))
      obviamente ajustando tus rangos e indicando la columna real donde estén los precios.. luego este resultado lo multiplicas por su número de unidades, acabando sumando todo

      Saludos

      Eliminar
  35. Hola Buen día, como puedo realizar una formula que me ayude a darle un valor especifico a un numero. En un formato necesito asignar una comisión para un concepto en especifico ejemplo:


    Específicamente quiero que el numero uno represente CONTRATO DE ANUALIDAD para que al poner el numero 1 me asigne un valor de 300 pesos. Y así sucesivamente con la siguiente tabla.

    ANUALIDAD 1 $300.00
    SEMESTRE 2 $200.00
    TRIMESTRE 3 $150.00
    CARGO RECURRENTE 4 $300.00

    Agradezco su ayuda.

    ResponderEliminar
    Respuestas
    1. Hola,
      creo te refieres a emplear un BUSCARV sobre tu tabla
      algo así, suponiendo que
      ANUALIDAD 1 $300.00
      SEMESTRE 2 $200.00
      TRIMESTRE 3 $150.00
      CARGO RECURRENTE 4 $300.00
      está en A1:C4
      en cualquier otra celda (H1) escribes ese número 1 (o 2 o 3 o 4) y en I1:
      =BUSCARV(H1;B1:C4;2;0)

      Slds

      Eliminar
  36. Buen dia tengo una serie de datos que quiero buscar en otro conjunto de datos con importes y que me traigha cierto texto o leyenda para aquellos que su valor sea negativo.

    ejemplo

    Datos A

    manzanas
    peras
    uvas

    Datos B

    Manzanas 10,000
    uvas -2,000
    Peras 100

    Quiero anotar la leyenda "negativo" cuando asi sea el resultado a un lado de la celda de los datos A.

    Espero su ayuda

    ResponderEliminar
    Respuestas
    1. Hola jcantu,
      podrías montar un condicional de este estilo:
      =SI(BUSCARV(celdaDatoA;TablaDatosB;2;0)<0;"negativo";"positivo")

      Saludos

      Eliminar
  37. Hola, gracias por tu ayuda, necesito una formula que:

    en hoja 1 tengo en la columna A números de facturas
    en hoja 2 Tengo en columna A tengo Números de Facturas, entonces en columna B necesito una formula que busque el valor en la otra hoja y si lo encuentra ponga si y si no lo encuentra ponga no, COMO una formula buscarv pero que no traiga el valor encontrado sino que ponga SI DE lo contrario ponga no.

    Muchas Gracias.

    ResponderEliminar
    Respuestas
    1. Hola,
      prueba con
      =SI(ESERROR(BUSCARV(...));"NO";"SI")
      Saludos

      Eliminar
  38. Genial!! me dio el resultado esperado!!! MAESTRO!!!

    ResponderEliminar
  39. COMO LE HAGO PARA BUSCAR EN UN COLUMNA DE UNA HOJA UN DATO, QUE ME SIRVE PARA OTRA HOJA, PERO SI SE REPITE EL MISMO DOCUMENTO CON DATOS DIFERENTES QUIERO DARLE EL DATO QUE YO QUIERO.

    HOJA 1

    TQM-01
    TQM-02 QUIERO QUE AQUI SALGA ADIOS Y NO HOLA
    TQM-03
    TQM-04

    HOJA 2

    TQM-02 HOLA
    TQM-02 ADIOS

    ResponderEliminar
    Respuestas
    1. Hola Lulú,
      no se si será extrapolable a tu situación real, pero en este caso, lo más sencillo sería ordenar los datos de la hoja 2 de la A a la Z por el segundo campo... luego aplicar en la hoja 1 un buscarv del código en el rango de la hoja2.
      O también INDICE y COINCIDIR con el argumento de coincidencia 1:
      =INDICE(col2 de la hoja2;COINCIDIR(dato de hoja1 TQM-02;col 1 de la hoja2;1))

      Saludos

      Eliminar
  40. HOLA BUENAS TARDES
    UN TALLER DONDE ME PREGUNTAN
    1. calcular el valor del pasaje teniendo en cuenta que: si la reserva se hace para aces; el valor del pasaje es a $ 350 cada kilómetro, ida y venida
    si la reserva se hace para avianca, el valor del pasaje es a $360 cada kilómetro, ida y venida. Si la reserva es air france: $ 450 ida y venida.

    ResponderEliminar
    Respuestas
    1. Hola!
      si la cuestión corresponde a un taller, supongo será algún tipo de ejercicio que debes intentar, o en todo caso ser explicado por tu tutor.
      De todas formas te doy la pista (posible solución):
      =SI(pasaje="aces";Num.Km*350;SI(pasaje="avianca";Num.Km*360SI(pasaje="air france";Num.Km*450)))
      Saludos

      Eliminar
  41. Hola, Guillermo estoy luchando con una formula que no consigo destrabar... Es una tabla de reservas que varía en funcion de los modelos del producto y los días que lo alquilan. He hecho una tabla 1 dias (del 1 al 120) y luego 4 columnas donde cada una es un producto en el que el precio va cambiando. quiero que, al poner un producto y los días que reserva, que me busque su precio correspondiente. Lo he conseguido solo con dos columnas pero al tener 4, no resuelvo montar la formula. =SI(L2=320;BUSCAR(F2;PRECIOS!$A$2:$B$120);BUSCAR(F2;PRECIOS!$A$2:$C$23))

    ResponderEliminar
    Respuestas
    1. Ya me he buscado la vida con una formula extra y a correr! Si te interesa y quieres darme algún consejo, será bienvenido, pero si no. No te preocupes.
      Gracias

      Eliminar
    2. Hola Guillermo,
      podrías emplear una función INDICE anidando en ella CONINCIDIR para determinar el número de fila correspondiente y su número de columna según día y producto..
      Saludos

      Eliminar
  42. hola tengo dos tablas:
    tabla de base
    dni - fecha - observacion
    xxxx dd-mm-aaaa puntual
    xxxx dd-mm-aaaa puntual
    xxxx dd-mm-aaaa tardanza

    tabla donde se desea mostrar informacion del campo observacion
    dni - fecha1 fecha2 fecha3 etc..
    xxxx (observacion) (observacion) (observacion) ...
    xxxx (observacion) (observacion) (observacion) ...
    xxxx (observacion) (observacion) (observacion)...

    gracias por tu gentil ayuda.

    saludos.

    ResponderEliminar
    Respuestas
    1. Hola Frank,
      siempre que las fechas sean finitas y determinadas, podrías construir la tabla de referencias cruzadas manualmente (en la primera fila las fechas y en la primera columna los diferentes DNI), luego basándote en esos criterios construir y anidar una fórmula UDF como la que se indica aquí:
      http://excelforo.blogspot.com.es/2014/12/vba-busqueda-doble-sobre-cualquier.html
      Saludos

      Eliminar
  43. Hola, antes de pedir ayuda...jejeje, quisiera agradecer por su gran aporte en el aprendizaje que buscamos,en este caso en excel.
    Bueno, quisiera que me ayudes con el siguiente caso:
    Usa la siguiente tabla de referencia para colocar la nota de los estudiantes en valores literales.
    TABLA DE REFERENCIA
    NÚMERO LETRA
    5 C
    6 C
    7 C
    8 C
    9 C
    10 C
    11 B
    12 B
    13 B
    14 B
    15 A
    16 A
    17 A
    18 A
    19 AD
    20 AD

    ALUMNO CALIFICACIÓN EQUIVALENCIA
    Julián 14
    Lorena 13
    Roberto 18
    Ricardo 12
    Carmen 16
    Rocio 6
    Gernimo 16
    Anahí 8
    Jesús 10
    Denis 16
    Miriam 7
    Angel 15
    Leonardo 9
    Janeth 11
    Daniel 17

    En lo que dice equivalencia considerar los valores literales.
    ¡el caso corresponde a la sesión: Función desref.

    ResponderEliminar
    Respuestas
    1. Hola J.Luis,
      puedes emplear un sencillo BUSCARV, añadiendo la función en la segunda tabla (campo equivalencia):
      =BUSCARV(calificación;Tabla1;2;0)
      Saludos

      Eliminar
  44. Buenos días, EXCELFORO.

    Mi inquietud es la siguiente:
    Tengo dos columnas donde manejo valores, ejemplo:

    A: 1,2,3,4,5,6,7,8,9
    B:10,11,12,13,14,15,16

    Con que formula puedo hacer que lea las dos columnas y si haya el valor me de el valor de una celda "C"

    Ejemplo: No encontró el valor en A pero si en B, que me de el valor que aparece en C.

    BUSCO EL VALOR 2115
    A5: 2110 B5:2115 C5: 100
    Como en la celda B5 está el valor que busco, debe darme el valor de la celda C5 donde sea que haga la formula, ya sea D5 (ejemplo).
    E intentado algo como esto:
    =SI.ERROR(BUSCARV(BUSCARV(A506;CoronaSantander!C:X;22;0);CoronaSantander!Q:X;8;0);"Pendiente por facturar")
    En este caso, busco el valor de A506 en la columa C y debe darme el valor de X y si no lo cuentra ps que haga una segunda busqueda en Q para que me de el valor de X. :/ Esto no me sirvió.
    Espero me hayas entendio y puedas ayudarme.

    ResponderEliminar
    Respuestas
    1. Hola
      Pues yo creo es algo similar:
      =SI.ERROR(BUSCARV(F5;$A$1:$C$10;3;0);SI.ERROR(BUSCARV(F5;$B$1:$C$10;2;0);"pdte"))
      en F5 lo que quieres buscar.
      Saludos

      Eliminar
    2. No se que tenia mal pero lo tuyo me funcionó. Muchas gracias.

      Eliminar
    3. Buenas tardes

      Como le hago para buscar el valor mas aproximado ya sea superior o inferior.

      Ejemplo

      Columna A

      5
      10
      13
      100
      120
      122
      105

      y si en otro base de datos tengo otra columna A con la siguiente informacion

      14
      101
      119

      Quiero que al hacer la busqueda de esta ultima informacion me arroje el resultado mas proximo ya sea inferior o superior, es decir que para el 14 me arroje el 13, para el 101 me de el 100 y para el 119 me arroje el 120.
      Como podras ver en el primero y segundo identifico el 13 y 100 que son los valores mas proximo inferiores y en el ultimo caso identifico el mas proximo superior.

      Te agradeceria mucho tu ayuida ya que llevo varios dias con esto y no he podido encontrar la formula.

      Gracias

      Eliminar
    4. Hola,
      interesante cuestión.
      Subiré en breve una respuesta en el blog

      Saludos

      Eliminar
    5. Ok Gracias Ismael, estare al pendiente porque la verdad si me urge. Saludos

      Eliminar
    6. Buen dia Ismael, tuviste oportunidad de revisar mi cuestionamiento? Aun no veo que hayas subido algo en el blog.

      Eliminar
  45. Buenas noches. Primero mil gracias por todo el conocimiento que comparte. Tengo un problema y no se como solucionarlo, puede que sea tonto pero no se como hacerlo.

    A
    123
    567
    890

    Necesito usar buscarv o similar para que me genere una alerta. Es decir, si digito un numero en una celda, busque en la columna A1, si esta el registro (ej 123) me diga "alerta", pero si no esta el registro (ej 999) me diga "no esta".

    Intente con esta formula pero solo me funciona para que me diga alerta, en los otros casos trae es el resultado de la busqueda (ej 123).

    =SI(BUSCARV(D2;A2:A3;1;0);"alerta";"no esta")

    Mil gracias por su colaboracion

    ResponderEliminar
    Respuestas
    1. Hola Andrés,
      prueba con:
      =SI(ESERROR(BUSCARV(D2;A2:A3;1;0));"NO ESTÁ";"alerta")

      Saludos

      Eliminar
  46. Hola Genios del excel
    TENGO UNA B.DATOS DONDE QUIERO CONTROLAR EL STOCK DE MERCADERIAS
    TENGO LOS CAMPOS Y Y NECESITO SABER SI CON BUSCAR V Y FUNCION SI ANIDADOS SE PUEDE

    MODELO MOTOR TENEDOR DEPOSITO ENT/SAL STOCK
    LPAA 13264 F.RIOS SAN LOREN COMPRAS 1
    LPAA 13264 A.MARTI LUQUE DEV 1
    LPAA 13264 P.ROSI CLIENTE ENTREGA 1


    NO SE EXPLICARLOS MUY BIEN PERO SI ALGUIEN PUEDE AYUDARME SE LOS AGRADECERIA.

    ResponderEliminar
  47. Hola , tengo una base de datos que discrimina tickets , anticipos , rendiciones. en una de las hojas tengo la formula contar si conjunto para contar los totales en la primera discriminando por usuario (numeri de ID de empleado) . y ahora necesitaria crear una columna que discrimine por ID del empleado la ultima carga de anticipo y la fecha en que se solicito

    ResponderEliminar
    Respuestas
    1. Hola
      tendría que ver la distribución de datos y del informe,
      Si puedes enviarme el fichero a
      excelforo@gmail.com
      Slds

      Eliminar
  48. Este comentario ha sido eliminado por el autor.

    ResponderEliminar
  49. Hola, gracias porque me han ayudado en varias ocaciones para resolver varias dudas; ahora tengo una y agradecería me pudieran realizar una recomendación de como resolverlo, el caso es el siguiente:
    Tengo una tabla 1 con una serie de varios artículos y fechas, y en otra tabla 2 tengo otra serie de artículos y fechas; lo que necesito es encontrar para la tabla 2 la fecha próxima anterior desde la tabla 1 para el mismo artículo. (cada artículo tiene n cantidad de fechas) Gracia

    ResponderEliminar
  50. si tengo una BD en la cual hay códigos, quisiera que en una celda me arroje "si" si se encontrara dicho codigo y "no" si no se encunetra nada.

    ResponderEliminar
    Respuestas
    1. Hola que tal estás...
      Un placer poder ayudarte.

      puedes aplicar un condicional con alguna función de búsqueda:
      =SI(ESERROR(BUSCARV(....));"no";"SI")

      Saludos

      Eliminar
  51. Hola , tengo una base de datos de Alumno,que tiene(ID,APELLIDO,NONBRE,SEX,FECH.NAC,EDAD) y estoy utilizando filtro avanzado y Macro.Necesito que los resultados si encuentra un Nºde Iden repetido indique
    su posición y le de un color en la celda para identificarlo,no se cómo hacerlo si pueden ayudarme.Gracias

    ResponderEliminar
  52. Buena.en mi escrito anterior dije que tenía una Base de Datos de Alumnos y los resultados los pasa a otra hoja llamada(Resultados).pero no he podido pasar con Macro a otra hoja llamada Nómina los datos para que me de los resultados(ID,APELLIDO,NOMBRE) y crear dos Botones uno para traer estos resultados y otro para Borrarlos.Gracias por tu Ayuda

    ResponderEliminar
    Respuestas
    1. Hola Carlos,
      cuál es la duda concreta???

      Slds

      Eliminar
    2. Gracias Ismael por responder,la duda que tengo es que no se como resaltar automáticamente en una macro con un color cuando los NºIdentidad son iguales.y la otra es que no he podido crear con Macro otra hoja llamada Nómina Alumnos,que me de solamente los resultados(ID,APELLIDO,NOMBRE) y poder crear dos Botones uno para traer estos resultados a la hoja Nómina Alumno y otro para Borrarlos.He tratado de hacerlo pero me sale un mensaje que no encuentra los datos.Gracias por tu Ayuda

      Eliminar
    3. Hola Carlos,
      más que una duda concreta parece que necesitas un desarrollo de las distintas etapas...
      Para resaltar con color Nº id iguales lo mejor es que apliques un formato condicional normal para encontrar duplicados.
      Para crear una hoja nueva puedes emplear la orden:
      Sheets.Add After:=ActiveSheet
      y la última parte de crear los botones podrías aplicar diferentes métodos, dependiendo del volumen de registros.

      Asegúrate, en todo caso, que te refieres a las hojas de origen y destino en todo el proceso de traspaso

      Slds

      Eliminar
  53. Este comentario ha sido eliminado por el autor.

    ResponderEliminar
  54. Hola Isamel, me ayudas con una duda, tengo que comparar y buscar en una sola celda varias alternativas, es decir, si(A1="azul",buscarv(etc) , y en la misma celda comparar blanco, rojo, negro y buscar en diferentes tablas el valor. como podría hacerlo? llevo rato intentando y no logro hacer la formula.. gracias de antemano.

    ResponderEliminar
    Respuestas
    1. Hola Juan
      intuyo que anidando un SI en otro (si no son muchos) puede ser una opción:
      =SI(A1="Azul";BUSCARV(..azul..);SI(A1="Blanco";BUSCARV(..blanco..);SI(A1="Rojo";BUSCARV(..rojo..); etc)))

      si fueran más colores habría que buscar alternativas... dependiendo de como estén los datos distribuidos por la hoja

      saludos

      Eliminar
  55. BUENOS DIAS NECESITO UNA AYUDA;

    TENGO VARIOS ARCHIVOS EN EXCEL DONDE SE LLEVA EL CONTROL DE LOS NUMEROS DE CERTIFICADOS, NECESITO BUSCAR RANGOS ESPECIFICOS EJEMPLO 19200 19300 BUSCAR EN TODAS LAS BASES EN LA COLUMNA CERTIFICADOS SI HAY NUMEROS DE ESE RANGO INLUYENDOLOS A ELLOS SI LOS HAY QUE LOS VAYA CONTANDO Y ME MUESTRE EL TOTAL DE LOS NUMEROS DEL RANGO QUE SE HAN UTILIZADO Y AQUELLOS QUE FALTAN POR USAR, ESTOS QUE NO SE HAN USADO ES PORQUE NO ESTAN EN LAS BASES. GRACIAS DE ANTEMANO.

    ResponderEliminar
    Respuestas
    1. Hola,
      lo siento, no me queda claro qué necesitas,
      pero creo que la función CONTAR.SI.CONJUNTO te podría servir por lo poco que entendí:
      =CONTAR.SI.CONJUNTO(rango_certificados;rango_certificados;">=1900";rango_certificados;"<=19300")

      algo así...

      Saludos

      Eliminar

Nota: solo los miembros de este blog pueden publicar comentarios.