VBA: Formas de copiar rangos o celdas.

Con asiduidad me llegan preguntas sobre la manera de copiar rangos o celdas de un lugar a otro de nuestros Libros de trabajos empleando macros. Por este motivo expondré con un ejemplo sencillo alguna de las formas más habituales en las que podemos conseguir un copiado de esos rangos de origen a uno de destino.
Para añadir un extra, le incorporaré una condición de pegado que controle que sólo se puede efectuar dicho copiado si algunas celdas no están vacías.

Algunas propiedades que también usaré en este ejemplo son:

• Application.CutCopyMode = False: con la que deshabilitaremos el modo Cortar y Copiar.


• Application.ScreenUpdating = False: desactiva la actualización de pantalla. Realiza todos los procesos sin que tengan un reflejo sobre lo que vemos.


• Application.ScreenUpdating = True: activa dicha actualización de pantalla.

Los códigos VBA de nuestra macro son:

Sub copiados()
Dim HojaOrigen As Worksheet, HojaDestino As Worksheet
  
Set HojaOrigen = Sheets(1)
Set HojaDestino = Sheets(2)
   
'con el If compruebo las condiciones previas a la ejecución del copiado y pegado
If HojaOrigen.Cells(2, 1).Value <> Empty And _
HojaOrigen.Cells(3, 1).Value <> Empty Then
Application.ScreenUpdating = False

'una forma empleando el método .Paste, con dos parámetros incompatibles
'o bien definimos Destination o bien Link
HojaOrigen.Cells(2, 1).Copy
    ActiveSheet.Paste HojaDestino.Range("A2")
'con Link realiza un Pegar vínculo
HojaOrigen.Cells(3, 1).Copy
    HojaDestino.Range("A3").Activate
    ActiveSheet.Paste link:=True
'Realizamos un Pegado especial, en este caso como Pegar valores y Pegar fórmulas
HojaOrigen.Cells(2, 2).Copy
    HojaDestino.Cells(2, 2).PasteSpecial Paste:=xlValues
HojaOrigen.Cells(3, 2).Copy
    HojaDestino.Cells(3, 2).PasteSpecial Paste:=xlFormulas
'Con el método .Copy podemos indicar dónde deseamos nos copie el rango seleccionado
'realiza un copiado exacto (con formatos, fórmulas, etc)
HojaOrigen.Cells(2, 3).Copy Destination:=HojaDestino.Cells(2, 3)
HojaOrigen.Cells(3, 3).Copy Destination:=HojaDestino.Cells(3, 3)
'También podemos vincular valores o fórmulas relacionando diferentes celdas.
HojaDestino.Range("D2").Value = HojaOrigen.Range("D2").Value
HojaDestino.Range("D3").Formula = HojaOrigen.Range("D3").Formula

Application.ScreenUpdating = True
Application.CutCopyMode = False
End If
Set HojaDestino = Nothing
Set HojaOrigen = Nothing
End Sub

La macro es muy sencilla, empleando las diferentes instrucciones seleccionamos distintas celdas de la Hoja1, y se van copiando en la Hoja2 en las celdas elegidas por nosotros.

Es importante observad las propiedades de cada orden dada, y cómo unas de ellas realizan copiados exactos (incluyendo formatos, fórmulas, etc) y otras sólo son copiados de los valores elegidos. Dependerá de nuestros requerimientos que usemos unas u otras.
En nuestro caso, tras ejecutar la macro, obtenemos el siguiente resultado en la Hoja2: